Manipulate

Manipulate[
Show[{
(* Plot of the surface *)
Plot3D[{9-x^2-y^2},{x,-2,2},{y,-2,2},Mesh->None,Boxed->False,Axes->False,PlotStyle->Directive[RGBColor[0.191241, 0.310857, 0.717601],Opacity[0.7]],PlotRange->{0,11},ViewVector->{10,5,20}],
(* Plot of the grid below *)
Graphics3D[{Black,Thin,Table[{Line[{{i,-2,0},{i,2,0}}],Line[{{-2,i,0},{2,i,0}}]},{i,-2,2}]}],
(* Plot of the tangent plane *)
Plot3D[{7-2(x-1)-2(y-1)},{x,0,2},{y,0,2},PlotStyle->Directive[Lighter[RGBColor[0.191241, 0.310857, 0.717601]],Opacity[0.7]],Mesh->None],
(* Plot of the point on the surface and its projection *)
Graphics3D[{Black,PointSize[Large],Point[{1,1,7}],Point[{1,1,0}],Dashed,Line[{{1,1,7},{1,1,0}}]}],
(* Plot of the curves on the surface of fixed y and fixed x *)
ParametricPlot3D[{x,1,9-x^2-1^2},{x,-2,2},PlotStyle->{Thick,Red}],
ParametricPlot3D[{1,y,9-1^2-y^2},{y,-2,2},PlotStyle->{Thick,Blue}],
(* Plot of the tangent vectors of the curves *)
Graphics3D[{
{Blue,Thick,Arrow[{{1,1,7},{1,2,5}}]},
{Red,Thick,Arrow[{{1,1,7},{2,1,5}}]},
{RGBColor[{0,128,128}/255],Thick,Arrow[{{1,1,7},{1+Cos[θ],1+Sin[θ],7-2(Cos[θ]+Sin[θ])}}]},
{Blue,Thick,Arrowheads[0.02],Arrow[{{1,1,0},{1,2,0}}]},{Red,Thick,Arrowheads[0.03],Arrow[{{1,1,0},{2,1,0}}]},
{RGBColor[{0,128,128}/255],Thick,Arrow[{{1,1,0},{1+Cos[θ],1+Sin[θ],0}}]}
}]
}],{{θ,Pi/6},0,2Pi,Pi/12},{{θ,Pi/6},0,2Pi,Pi/12,ControlType->InputField}]