Parabolic Parametric Curve Example

We have used -10≤t≤10 to approximate the domain (-∞,+∞).  
We have used the PlotRange option to specify the “window” that we see.

ParametricPlot[{t^2-2t,t+1},{t,-10,10},PlotRange->{{-10,10},{-10,10}}]

When the domain is [0,4], the entire curve fits in the “window” [-10,10]×[-10,10].

ParametricPlot[{t^2-2t,t+1},{t,0,4},PlotRange->{{-10,10},{-10,10}}]

Here I have solved for the initial and terminal points and have animated the particle traveling along the path.

initial={t^2-2t,t+1}/.t->0
terminal={t^2-2t,t+1}/.t->4
Manipulate[
Show[
ParametricPlot[{t^2-2t,t+1},{t,0,4},PlotRange->{{-10,10},{-10,10}}],
Graphics[{PointSize[Large],Point[initial],Point[terminal],Red,Point[{tt^2-2tt,tt+1}]}]],{tt,0,4}]

Parametrizing a circle

ParametricPlot[{Cos[t],Sin[t]},{t,0,2Pi},PlotRange->2]

Manipulate[
Show[
ParametricPlot[{Cos[t],Sin[t]},{t,0,tt},PlotRange->2],
Graphics[{PointSize[Large],Red,Point[{Cos[tt],Sin[tt]}]}]],{tt,0.1,2Pi}]

What about <cos(t)+h,sin(t)+k>?

ParametricPlot[{Cos[t]+1,Sin[t]-1},{t,0,2Pi},PlotRange->2]

Manipulate[
Show[
ParametricPlot[{Cos[t]+h,Sin[t]+k},{t,0,2Pi},PlotRange->{{-5,5},{-5,5}},Ticks->{Range[-5,5]}],
Graphics[{PointSize[Large],Red,Point[{h,k}]}]
],
{{h,0},-4,4,1},{{k,0},-4,4,1},ControlType->Setter]

What about <a cos(t),b sin(t)>?

Manipulate[
Show[
ParametricPlot[{a Cos[t],b Sin[t]},{t,0,2Pi},PlotRange->{{-5,5},{-5,5}},Ticks->{Range[-5,5]}],
Graphics[{Thick,Red,Line[{{a,0},{0,0},{0,b}}],PointSize[Large],Point[{a,0}],Point[{0,b}]}]
],
{{a,1},-4,4,1},{{b,1},-4,4,1},ControlType->Setter]

Fun curves

Lissajous

ParametricPlot[{Cos[3u],Sin[5u]},{u,0,2Pi}]

Curves from the book

Manipulate[
ParametricPlot[{t^2, t^3-c t},{t,-10,10},PlotRange->50],{c,0,20}]

Swallowtail Catastrophe Curves

Manipulate[
ParametricPlot[{2c t-4t^3,-c t^2+3t^4},{t,-10,10},PlotRange->50],{c,0,20}]

Other Famous Curves

ParametricPlot[{Cos[t]-Cos[10t],Sin[t]-Sin[10t]},{t,0,2Pi}]

Evaluate this command:

Make your own!!!!!

3D Vector Functions

Use ParametricPlot3D to plot the curves associated with 3D Vector Functions

ParametricPlot3D[{Cos[t],Sin[t],0},{t,-3Pi,3Pi},PlotRange->2]

ParametricPlot3D[{0,0,t},{t,-3Pi,3Pi},PlotRange->3Pi]

ParametricPlot3D[{Cos[t],Sin[t],t},{t,-3Pi,3Pi},PlotRange->3Pi]

Manipulate[
Show[
ParametricPlot3D[{Cos[t],Sin[t],t},{t,-3Pi,3Pi},PlotRange->3Pi],
Graphics3D[{PointSize[Large],Red,Point[{Cos[tt],Sin[tt],tt}]}]],{tt,-3Pi,3Pi}]

What happens if you change the order of the variables?

ParametricPlot3D[{Cos[t],t,Sin[t]},{t,-3Pi,3Pi},PlotRange->3Pi]

Other examples from the book

Twisted Cubic

ParametricPlot3D[{t,t^2,t^3},{t,-2,2},PlotRange->3]

Manipulate[
Show[
ParametricPlot3D[{t,t^2,t^3},{t,-2,2},PlotRange->3],
Graphics3D[{PointSize[Large],Red,Point[{tt,tt^2,tt^3}]}]],{tt,-1.45,1.45}]

Trefoil Knot

ParametricPlot3D[{(2+Cos[1.5t])Cos[t],(2+Cos[1.5t])Sin[t],Sin[1.5t]},{t,0,4Pi},PlotRange->3]

Toroidal Spiral

ParametricPlot3D[{(4+Sin[20t])Cos[t],(4+Sin[20t])Sin[t],Cos[20t]},{t,0,2Pi},PlotRange->6]

Make your own!!!!!