MWE: Extracting Mesh Information

Here is a BoundaryMeshRegion

mesh=BoundaryDiscretizeGraphics[Ellipsoid[{0,0,0},{1,.5,.5}],MaxCellMeasure->.05]

Find the coordinates of all the vertices

vertices=MeshCoordinates[mesh]

Visualize them

Graphics3D[Map[Point,vertices]]

Find the skeleton of the mesh

We want the 1D components of our mesh.

edges=MeshPrimitives[mesh,1];

Graphics3D[edges]

Adding some thickness

Graphics3D[Map[Tube[#,.02]&,edges[[All,1]]]]

Create a 3D Printable version

(This requires adding spheres at the ends of all the tubes.

Graphics3D[{
Map[Sphere[#,.02]&,vertices],
Map[Tube[#,.02]&,edges[[All,1]]]
}]

Here’s the code to export the STL file

(*Export[NotebookDirectory[]<>"wireframe.stl",%]*)

Extract the polygons that form the boundary of the object

We want the 2D components of our mesh.

polygons=MeshPrimitives[mesh,2];

Here are 100 of them.

Graphics3D[polygons[[1;;100]]]

Let’s color them randomly

colors=Table[Hue[RandomReal[]],Length[polygons]];
Graphics3D[MapThread[{#1,#2}&,{colors,polygons}]]

Algorithmically color them based on their x-coordinate

Here is the center of the vertices of a polygon:

Mean[polygons[[1,1]]]

We take the first coordinate and rescale by a factor of 3.

colors=Table[Hue[Mean[polygons[[i,1]]][[1]]/3],{i,Length[polygons]}];
Graphics3D[MapThread[{#1,#2}&,{colors,polygons}]]